Список форумов AmiSite.ru AmiSite.ru
Форум по Ами
 FAQ  •  Поиск  •  Пользователи  •  Группы   •  Регистрация  •  Профиль  •  Войти и проверить личные сообщения  •  Вход
 Автоматическое резервирование интернет канала Следующая тема
Предыдущая тема
Начать новую тему  Ответить на тему
Автор Сообщение
GREEN_X5



Зарегистрирован: 13.04.2012
Сообщения: 135

СообщениеДобавлено: Вт Сен 10, 2013 11:13 am Ответить с цитатой Вернуться к началу

Для стабильной функциональности робота нужен стабильный доступ в интернет, а выбранный нами вроде бы надежный провайдер иногда затыкается, поэтому нелишне подстраховаться например 3G интернетом от мобильного провайдера или ещё одним проводным.
Я поставил 3G роутер от Мегафон в ту же домашнюю сеть 255.255.255.0, т.е соединил его с точкой доступа основного провайдера прямым кабелем lan-lan, назначил IP адреса точкам доступа 192.168.1.1 и 192.168.1.2. Торговый терминал с роботом имеет любой адрес в той же подсети, динамический или в обход DHCP, например 192.168.1.5 и соединен по wi-fi с любой точкой доступа.
Дальше дело за малым, создаем блокнотом текстовый файл, копируем туда код, сохраняем, переименовываем расширение в .bat, называем например autogate, запускаем. Автогейт пропишет маршруты для пинга двух DNS серверов Norton и с помощью них проверяет в интернете ли наши шлюзы и перекидывает маршруты на резервный (например 3G Мегафон) когда основной провайдер оставил нас без инета (проверка каждый 3 сек). Как только инет появляется у основного провайдера (слежка каждые 10 сек), Автогейт возвращает маршрут к основному провайдеру.
Образец взят из инета, но изменен концептуально - компьютер не разрывает соединение с одним роутером чтобы соединиться с другим (это долго), а просто меняет маршрут (это быстро, молниеносно).
Тело файла autogate.bat
Код:
@echo off
Color 1f
SetLocal EnableExtensions EnableDelayedExpansion
CHCP 866 >nul

set NR=Ростелеком
set GR=192.168.1.1
set IR=198.153.192.1
set NM=Мегафон
set GM=192.168.1.2
set IM=198.153.194.1

set Z=0.0.0.0 & set F=255.255.255.255 >nul
route add %Z% mask %Z% %GR% >nul
route add %IR% %GR% >nul & route add %IM% %GM% >nul
set repR=проверка шлюза && set repM=проверка шлюза

:startt
Call :raport
ping -f -n 2 -l 1 %GR%|find/I "TTL=" >nul
If %ERRORLEVEL%==0 set repR=шлюз найден && set repM=не проверено && goto first_ping
ping -f -n 2 -l 1 %GM%|find/I "TTL=" >nul
If %ERRORLEVEL%==1 set repR=шлюз не найден && set repM=шлюз не найден  && ping -n 5 127.0.0.1 >nul && goto startt

:first_ping
Call :raport
ping -f -n 2 -l 1 %IR%|find/I "TTL=" >nul
If %ERRORLEVEL%==0  set repR=подключено && set repM=не проверено && ping -n 5 127.0.0.1 >nul && goto first_ping
ping -f -n 2 -l 1 %IM%|find/I "TTL=" >nul
if %ERRORLEVEL%==1 set repR=нет интернета && set repM=нет интернета && goto first_ping
goto reserve

:second_ping
Call :raport
ping -f -n 2 -l 1 %IR%|find/I "TTL=" >nul
if %ERRORLEVEL%==0 set repR=пинг появился && set repM=не проверено && goto first
ping -f -n 2 -l 1 %IM%|find/I "TTL=" >nul
if %ERRORLEVEL%==1 set repR=нет интернета && set repM=нет интернета && goto first
ping -n 10 127.0.0.1 >nul
goto second_ping

:reserve
Call :raport
route change %Z% mask %Z% %GM% >nul
ping -f -n 2 -l 1 %IM%|find/I "TTL=" >nul
if %ERRORLEVEL%==0 set repR=нет интернета && set repM=подключено && goto second_ping

:first
Call :raport
route change %Z% mask %Z% %GR% >nul
ping -f -n 2  -l 1 %IR%|find/I "TTL=" >nul
If %ERRORLEVEL%==1 set repR=нет интернета && set repM=не проверено && goto first_ping
if %ERRORLEVEL%==0 set repR=подключено && set repM=не проверено && goto first_ping

:raport
Cls
echo --%NR%--
echo %repR%
echo =============
echo ---%NM%---
echo %repM%
exit /b 0


Меняем параметры под свою сеть и имена провайдеров в начале кода

set NR=Ростелеком (имя основного провайдера)
set GR=192.168.1.1 (IP точки доступа основного провайдера)
set IR=198.153.192.1 (публичный DNS, можно не менять)
set NM=Мегафон (имя резервного провайдера)
set GM=192.168.1.2 (IP точки доступа резервного провайдера)
set IM=198.153.194.1 (второй публичный DNS, можно не менять)

Если что-то не так настроили и комп остался без инета, перегрузите комп и маршруты сбросятся. Ищите свои ошибки с настройками и сетью, т.к. код 100% рабочий.
Накладные расходы трафика крайне незначительны т.к. пингует однобайтными пакетами,когда сидим на основном канале - примерно 20 МБ в месяц при круглосуточной работе, расход 3G трафика - ноль.
Всем профита.
Посмотреть профиль Отправить личное сообщение
000
Site Admin


Зарегистрирован: 10.12.2007
Сообщения: 8369

СообщениеДобавлено: Вт Сен 10, 2013 12:44 pm Ответить с цитатой Вернуться к началу

Спасибо!!!

_________________
ceterum censeo carthaginem esse delendam
Удачи. Олег.
Посмотреть профиль Отправить личное сообщение Посетить сайт автора
Aleksandr



Зарегистрирован: 13.11.2011
Сообщения: 56

СообщениеДобавлено: Пн Мар 27, 2017 4:25 pm Ответить с цитатой Вернуться к началу

[quote="GREEN_X5"]Для стабильной функциональности робота нужен стабильный доступ в интернет....
Здравствуйте . Вопрос по разрыву соединения . Где то была программа
по автоматическому соединению для QUIK . Может кто знает ?
Посмотреть профиль Отправить личное сообщение
Aleksandr



Зарегистрирован: 13.11.2011
Сообщения: 56

СообщениеДобавлено: Вт Мар 28, 2017 6:14 am Ответить с цитатой Вернуться к началу

[quote="Aleksandr"]
GREEN_X5 писал(а):
Для стабильной функциональности робота нужен стабильный доступ в интернет....
Здравствуйте . Вопрос по разрыву соединения . Где то была программа
по автоматическому соединению для QUIK . Может кто знает ?

Вопрс снят .Нашёл на QUIKе
Посмотреть профиль Отправить личное сообщение
Показать сообщения:      
Начать новую тему  Ответить на тему


 Перейти:   



Следующая тема
Предыдущая тема
Вы не можете начинать темы
Вы не можете отвечать на сообщения
Вы не можете редактировать свои сообщения
Вы не можете удалять свои сообщения
Вы не можете голосовать в опросах
Вы не можете вкладывать файлы
Вы не можете скачивать файлы


Powered by phpBB © 2001, 2002 phpBB Group :: FI Theme :: Часовой пояс: GMT + 3

File Attachment © by Meik Sievertsen